Otmanix Blog – English language edition

VADP Image backups are possible with latest versions of EMC Networker backup software. Enabling CBT for Windows virtual machines improves backup speed.

Here’s a script for enabling/disabling CBT or reading CBT status.

@ECHO OFF
 :BEGIN
 REM change block tracking for VMware/Networker
 REM tested with Networker 7.6.3.1 on Windows 7 and VSphere 5
 REM 08.02.2012 Otmanix
 REM http://www.punchingclouds.com/?p=896
 REM http://kb.vmware.com/selfservice/microsites/search.do?language=en_US&cmd=displayKC&externalId=1020128
 CLS
 ECHO *** change block tracking - VMware/Networker ***
 ECHO ************************************************
 SET /P VCENTER=vcenter (FQDN):
 SET /P USER=user:
 SET /P PASSWORD=password:
 :ID
 CLS
 ECHO identify vm by
 ECHO 1) name in vcenter
 ECHO 2) dns name (fqdn)
 ECHO 3) ip address
 ECHO 4) EXIT
 CHOICE /N /C 1234 /M "PICK A NUMBER (1, 2, 3, 4)"
 IF ERRORLEVEL 4 GOTO END
 IF ERRORLEVEL 3 GOTO ID3
 IF ERRORLEVEL 2 GOTO ID2
 IF ERRORLEVEL 1 GOTO ID1
 IF ERRORLEVEL 0 GOTO END
 GOTO ID
 :ID3
 SET LOOKUPMETHOD=ip-addr
 SET LOOKUPKEY=
 SET /P LOOKUPKEY=IP address:
 GOTO CBT
 :ID2
 SET LOOKUPMETHOD=dns-name
 SET LOOKUPKEY=
 SET /P LOOKUPKEY=hostname (fqdn):
 GOTO CBT
 :ID1
 SET LOOKUPMETHOD=vm-name
 SET LOOKUPKEY=
 SET /P LOOKUPKEY=name of vm in vcenter (case sensitive):
 GOTO CBT
 :CBT
 CLS
 ECHO choose
 ECHO 1) info about cbt
 ECHO 2) enable cbt
 ECHO 3) disable CBT
 ECHO 4) EXIT
 CHOICE /N /C 1234 /M "PICK A NUMBER (1, 2, 3, 4)"
 IF ERRORLEVEL 4 GOTO END
 IF ERRORLEVEL 3 GOTO CBT3
 IF ERRORLEVEL 2 GOTO CBT2
 IF ERRORLEVEL 1 GOTO CBT1
 IF ERRORLEVEL 0 GOTO END
 GOTO BEGIN
 :CBT3
 SET CBTMODE=cbt-disable
 GOTO COMMAND
 :CBT2
 SET CBTMODE=cbt-enable
 GOTO COMMAND
 :CBT1
 SET CBTMODE=info
 GOTO COMMAND
 :COMMAND
 nsrvadp_modify_vm.exe -H %VCENTER% -P https -u %USER% -p %PASSWORD% -l %LOOKUPMETHOD% -k %LOOKUPKEY% -c %CBTMODE%
 PAUSE
 GOTO CBT
 :END